MSA-1255: The following app submitted will be an endpoint for our IOS app Gidjit.

Gidjit is like having a home screen based on your environment. It scans your surroundings looking for home devices, personal electronic devices, times and locations of interest, and more. It will present a list of corresponding launcher panels that allow you to quickly access actions like open an app, control/monitor a device, execute a SmartThings Routine, or link to the control/launch screen of a device. For example based on the users location they will quickly be able to access a preset routine. We are really looking forward to having SmartThings in integration with the app. 

Link: https://itunes.apple.com/us/app/gidjit-smart-launcher/id961388659?mt=8

The app currently will not have the SmartThing's support until the next version that will be released when this is hopefully approved, as we will also have to go through the Apple approval process allowing them to test the features.

Thank you for your time!

Matt

devicetypes/a4refillpad/orvibo-contact-sensor.src/orvibo-contact-sensor.groovy

@@ -1,126 +0,0 @@
-/**
- *  Orvibo Contact Sensor
- * 
- *  Copyright Wayne Man 2016
- * 
- *  Licensed under the Apache License, Version 2.0 (the "License"); you may not use this file except
- *  in compliance with the License. You may obtain a copy of the License at:
- *
- *      http://www.apache.org/licenses/LICENSE-2.0
- *
- *  Unless required by applicable law or agreed to in writing, software distributed under the License is distributed
- *  on an "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the License
- *  for the specific language governing permissions and limitations under the License.
- *
- *  Orvibo Contact Sensor Device Type
- *  Battery levels updates periodically, for an instant update press physical button on sensor once
- *  30/04/2016 fixed fingerprint
- *  09/05/2016 added heartbeat to help track if sensor is alive (recommend using a devicecheck smartapp)
- */
-metadata {
-	definition (name: "Orvibo Contact Sensor", namespace: "a4refillpad", author: "Wayne Man") {
-		capability "Contact Sensor"
-		capability "Sensor"
-        	capability "Battery"
-
-		fingerprint inClusters: "0000,0001,0003,0500", manufacturer: "\u6B27\u745E", model: "75a4bfe8ef9c4350830a25d13e3ab068"
-
-	}
-
-	// simulator metadata
-	simulator {
-		// status messages
-		status "open":   "zone report :: type: 19 value: 0031"
-		status "closed": "zone report :: type: 19 value: 0030"
-	}
-
-    	tiles(scale: 2) {
-		multiAttributeTile(name:"contact", type: "lighting", width: 6, height: 4) {
-			tileAttribute ("device.contact", key: "PRIMARY_CONTROL") {
-           		attributeState("open", label:'open', icon:"st.contact.contact.open", backgroundColor:"#ffa81e")
-            	attributeState("closed", label:'closed', icon:"st.contact.contact.closed", backgroundColor:"#79b821")   
- 			}
-		}
-        
-        valueTile("battery", "device.battery", inactiveLabel: false, width: 2, height: 2, decoration: "flat") {
-            state "battery", label:'${currentValue}% battery', unit:""
-        }    
-        
-		main "contact"
-		details(["contact", "battery"])
-	}
- 
-}
-
-// Parse incoming device messages to generate events
-def parse(String description) {
-	def name = null
-	def value = description
-   	def descriptionText = null
-   	def now = new Date()
-    log.debug "Parsing: ${description}"
-    Map map = [:]
-
-	List listMap = []
-	List listResult = []
-  
-    
-	if (zigbee.isZoneType19(description)) {
-		name = "contact"
-		value = zigbee.translateStatusZoneType19(description) ? "open" : "closed"
-	} else if(description?.startsWith("read attr -")) {
-    	map = parseReportAttributeMessage(description)
-    }
-	
-	def result = createEvent(name: name, value: value)
-	log.debug "Parse returned ${result?.descriptionText}"
-//  send event for heartbeat    
-    	sendEvent(name: "heartbeat", value: now)
-	listResult << result
-    
-   	if (listMap) {
-        for (msg in listMap) {
-            listResult << createEvent(msg)
-        }
-    }
-    else if (map) {
-        listResult << createEvent(map)
-    }
-
-	log.debug "Parse returned ${result?.descriptionText}"
-	return listResult
-} 
-
-private Map parseReportAttributeMessage(String description) {
-	Map descMap = (description - "read attr - ").split(",").inject([:]) {
-		map, param -> def nameAndValue = param.split(":")
-		map += [(nameAndValue[0].trim()):nameAndValue[1].trim()]
-	}
-	Map resultMap = [:]
-
-	log.info "IN parseReportAttributeMessage()"
-	log.debug "descMap ${descMap}"
-
-	switch(descMap.cluster) {
-		case "0001":
-			log.debug "Battery status reported"
-
-			if(descMap.attrId == "0021") {
-				resultMap.name = 'battery'
-                resultMap.value = (convertHexToInt(descMap.value) / 2)
-                log.debug "Battery Percentage convert to ${resultMap.value}%"
-			}
-			break
-		default:
-			log.info descMap.cluster
-			log.info "cluster1"
-			break
-	}
-
-	log.info "OUT parseReportAttributeMessage()"
-	return resultMap
-}
-
-private Integer convertHexToInt(hex) {
-	Integer.parseInt(hex,16)
-}

devicetypes/smartthings/aeon-home-energy-meter-c3.src/aeon-home-energy-meter-c3.groovy

@@ -94,11 +94,11 @@ def parse(String description) {
 	def cmd = zwave.parse(description, [0x31: 1, 0x32: 1, 0x60: 3])
 	if (cmd) {
 		result = createEvent(zwaveEvent(cmd))
-		log.debug "Parse returned ${result?.descriptionText}"
-		storeGraphData(result.name, result.value)
-	} else {
-		log.debug "zwave.parse returned null command. Cannot create event"
 	}
+	log.debug "Parse returned ${result?.descriptionText}"
+
+	storeGraphData(result.name, result.value)
+
 	return result
 }
 

devicetypes/smartthings/hue-bloom.src/hue-bloom.groovy

@@ -37,6 +37,9 @@ metadata {
 			tileAttribute ("device.level", key: "SLIDER_CONTROL") {
 				attributeState "level", action:"switch level.setLevel", range:"(0..100)"
             }
+            tileAttribute ("device.level", key: "SECONDARY_CONTROL") {
+	            attributeState "level", label: 'Level ${currentValue}%'
+			}
 			tileAttribute ("device.color", key: "COLOR_CONTROL") {
 				attributeState "color", action:"setAdjustedColor"
 			}

devicetypes/smartthings/hue-bulb.src/hue-bulb.groovy

@@ -38,6 +38,9 @@ metadata {
 			tileAttribute ("device.level", key: "SLIDER_CONTROL") {
 				attributeState "level", action:"switch level.setLevel", range:"(0..100)"
             }
+            tileAttribute ("device.level", key: "SECONDARY_CONTROL") {
+	            attributeState "level", label: 'Level ${currentValue}%'
+			}
 			tileAttribute ("device.color", key: "COLOR_CONTROL") {
 				attributeState "color", action:"setAdjustedColor"
 			}

devicetypes/smartthings/hue-lux-bulb.src/hue-lux-bulb.groovy

@@ -33,6 +33,9 @@ metadata {
             tileAttribute ("device.level", key: "SLIDER_CONTROL") {
               attributeState "level", action:"switch level.setLevel", range:"(0..100)"
             }
+            tileAttribute ("device.level", key: "SECONDARY_CONTROL") {
+	            attributeState "level", label: 'Level ${currentValue}%'
+			}
         }
 
         controlTile("levelSliderControl", "device.level", "slider", height: 1, width: 2, inactiveLabel: false, range:"(0..100)") {

devicetypes/smartthings/tile-ux/tile-multiattribute-generic.src/tile-multiattribute-generic.groovy

@@ -110,7 +110,7 @@ def installed() {
 	sendEvent(name: "multilineText", value: "Line 1 YES\nLine 2 YES\nLine 3 NO")
 }
 
-def parse(String description) {
+def parse() {
 	// This is a simulated device. No incoming data to parse.
 }
 

smartapps/com-gidjit-smartthings-hub/gidjit-hub.src/gidjit-hub.groovy

@@ -0,0 +1,252 @@
+/**
+ *  Gidjit Hub
+ *
+ *  Copyright 2016 Matthew Page
+ *
+ *  Licensed under the Apache License, Version 2.0 (the "License"); you may not use this file except
+ *  in compliance with the License. You may obtain a copy of the License at:
+ *
+ *      http://www.apache.org/licenses/LICENSE-2.0
+ *
+ *  Unless required by applicable law or agreed to in writing, software distributed under the License is distributed
+ *  on an "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the License
+ *  for the specific language governing permissions and limitations under the License.
+ *
+ */
+definition(
+    name: "Gidjit Hub",
+    namespace: "com.gidjit.smartthings.hub",
+    author: "Matthew Page",
+    description: "Act as an endpoint so user's of Gidjit can quickly access and control their devices and execute routines. Users can do this quickly as Gidjit filters these actions  based on their environment",
+    category: "Convenience",
+    iconUrl: "http://www.gidjit.com/appicon.png",
+    iconX2Url: "http://www.gidjit.com/appicon@2x.png",
+    iconX3Url: "http://www.gidjit.com/appicon@3x.png",
+    oauth: [displayName: "Gidjit", displayLink: "www.gidjit.com"])
+
+
+
+preferences {
+  section ("Allow Gidjit to have access, there by allowing you to quickly control and monitor the following devices") {
+    input "switches", "capability.switch", title: "Control/Monitor your switches", multiple: true, required: false
+    input "thermostats", "capability.thermostat", title: "Control/Monitor your thermostats", multiple: true, required: false
+    input "windowShades", "capability.windowShade", title: "Control/Monitor your window shades", multiple: true, required: false //windowShade
+    //input "bulbs", "capability.colorControl", title: "Control your lights", multiple: true, required: false //windowShade
+
+  }
+}
+mappings {
+  path("/structureinfo") {
+    action: [
+      GET: "structureInfo"
+    ]
+  }
+  path("/helloactions") {
+    action: [
+      GET: "helloActions"
+    ]
+  }
+  path("/helloactions/:label") {
+    action: [
+      PUT: "executeAction"
+    ]
+  }
+
+  path("/switch/:id/:command") {
+    action: [
+      PUT: "updateSwitch"
+    ]
+  }
+
+  path("/thermostat/:id/:command") {
+    action: [
+      PUT: "updateThermostat"
+    ]
+  }
+
+  path("/windowshade/:id/:command") {
+    action: [
+      PUT: "updateWindowShade"
+    ]
+  }
+  path("/acquiredata/:id") {
+    action: [
+      GET: "acquiredata"
+    ]
+  }
+}
+
+
+def installed() {
+	log.debug "Installed with settings: ${settings}"
+
+	initialize()
+}
+
+def updated() {
+	log.debug "Updated with settings: ${settings}"
+
+	unsubscribe()
+	initialize()
+}
+
+def initialize() {
+	// subscribe to attributes, devices, locations, etc.
+}
+def helloActions() {
+	def actions = location.helloHome?.getPhrases()*.label
+    if(!actions) {
+    	return []
+    }
+	return actions
+}
+def executeAction() {
+    def actions = location.helloHome?.getPhrases()*.label
+    def a = actions?.find() { it == params.label }
+    if (!a) {
+        httpError(400, "invalid label $params.label")
+        return
+    }
+    location.helloHome?.execute(params.label)
+}
+/*  this is the primary function called to query at the structure and its devices */
+def structureInfo() { //list all devices
+	def list = [:]
+    def currId = location.id
+    list[currId] = [:]
+    list[currId].name = location.name
+    list[currId].id = location.id
+    list[currId].temperatureScale = location.temperatureScale
+    list[currId].devices = [:]
+  
+    def setValues = {
+   		if (params.brief) {
+            return [id: it.id, name: it.displayName]
+        }
+        def newList = [id: it.id, name: it.displayName, suppCapab: it.capabilities.collect {
+            "$it.name"
+        }, suppAttributes: it.supportedAttributes.collect {
+            "$it.name"      
+        }, suppCommands: it.supportedCommands.collect {
+            "$it.name"      
+        }]
+
+        return newList
+    }
+    switches?.each {
+      list[currId].devices[it.id] = setValues(it)
+    }
+    thermostats?.each {
+      list[currId].devices[it.id] = setValues(it)
+    }
+    windowShades?.each {
+      list[currId].devices[it.id] = setValues(it)
+    }
+
+    return list
+
+}
+/*  This function returns all of the current values of the specified Devices attributes */
+def acquiredata() {
+	def resp = [:]
+    if (!params.id) {
+    	httpError(400, "invalid id $params.id")
+        return
+    }
+    def dev = switches.find() { it.id == params.id } ?: windowShades.find() { it.id == params.id } ?:
+    	thermostats.find() { it.id == params.id }    
+   
+    if (!dev) {
+    	httpError(400, "invalid id $params.id")
+        return    
+    }
+    def att = dev.supportedAttributes
+    att.each {
+    	resp[it.name] = dev.currentValue("$it.name")
+    }
+    return resp
+}
+
+void updateSwitch() {
+    // use the built-in request object to get the command parameter
+    def command = params.command
+	def sw = switches.find() { it.id == params.id }
+    if (!sw) {
+    	httpError(400, "invalid id $params.id")
+        return
+    }
+    switch(command) {
+        case "on":
+        	if ( sw.currentSwitch != "on" ) {
+            	sw.on()
+            }
+            break
+        case "off":
+        	if ( sw.currentSwitch != "off" ) {
+            	sw.off()
+            }
+            break
+        default:
+            httpError(400, "$command is not a valid")
+    }
+}
+
+
+void updateThermostat() {
+    // use the built-in request object to get the command parameter
+    def command = params.command
+	def therm = thermostats.find() { it.id == params.id }
+    if (!therm || !command) {
+    	httpError(400, "invalid id $params.id")
+        return
+    }
+    def passComm = [
+        "off",
+        "heat",
+        "emergencyHeat",
+        "cool",
+        "fanOn",
+        "fanAuto",
+        "fanCirculate",
+        "auto"
+
+	]
+    def passNumParamComm = [
+    	"setHeatingSetpoint",
+    	"setCoolingSetpoint",   
+    ]
+    def passStringParamComm = [
+        "setThermostatMode",
+        "setThermostatFanMode",
+	]
+    if (command in passComm) {
+    	therm."$command"()	
+    } else if (command in passNumParamComm && params.p1 && params.p1.isFloat()) {
+    	therm."$command"(Float.parseFloat(params.p1))	
+    } else if (command in passStringParamComm && params.p1) {
+    	therm."$command"(params.p1)	
+    } else {
+    	httpError(400, "$command is not a valid command")
+    }
+}
+
+void updateWindowShade() {
+    // use the built-in request object to get the command parameter
+    def command = params.command
+	def ws = windowShades.find() { it.id == params.id }
+    if (!ws || !command) {
+    	httpError(400, "invalid id $params.id")
+        return
+    }
+    def passComm = [
+		"open",
+        "close",
+        "presetPosition",
+	]
+    if (command in passComm) {
+    	ws."$command"()		
+    } else {
+    	httpError(400, "$command is not a valid command")
+    }
+}
+// TODO: implement event handlers